EasyLanguage SuperTrend indicator

March 25th, 2010, 03:01 AM

Here is my version of a TradeStation/MultiCharts EasyLanguage SuperTrend indicator.

I made it a function so it could be called easily from a strategy.

Function:

Code

                            
// SuperTrend function 
// March 25 2010
// Big Mike https://nexusfi.com

inputs: 
ATRLength(NumericSimple), ATRMult(NumericSimple), Strength(NumericSimple), STrend(NumericRef);

vars: 
ATR(0), 
avg(0), 
dn(0), 
up(0), 
trend(1), 
flag(0), 
flagh(0), 
ST(0),
hl(0); 


hl = Highest(High, ATRLength) - Lowest(Low, ATRLength);
ATR = XAverage(hl, ATRLength);
avg = (XAverage(high, Strength) + XAverage(low, Strength))/2;
up = avg + ATR; 
dn = avg - ATR; 

if c > up[1] and c > Highest(High, Strength)[1] then
trend = 1
else if c < dn[1] and c < Lowest(Low, Strength)[1] then
trend = -1;


if trend < 0 and trend[1] > 0 then flag=1 else flag=0; 
if trend > 0 and trend[1] < 0 then flagh = 1 else flagh = 0; 

if trend > 0 and dn < dn[1] then dn=dn[1];
if trend < 0 and up > up[1] then up=up[1];

if flag = 1 then up = avg + ATR; 
if flagh = 1 then dn = avg - ATR; 

if trend = 1 then ST = dn else ST = up;
SuperTrend = ST;
STrend = trend;

Please note, on my version I use personally, the line "avg = (XAverage(high, Strength) + XAverage(low, Strength))/2;" from above function uses a Jurik-like phased moving average, not XAverage(EMA). But I haven't posted that yet, so I just made this use XAverage instead. Replace with your favorite MA.

Indicator:

Code

                            
// SuperTrend indicator
// March 25 2010
// Big Mike https://nexusfi.com 

inputs: 
ATRLength(9), ATRMult(1), Strength(9);

vars: 
strend(0),
st(0);

st = SuperTrend(ATRLength, ATRMult, Strength, strend);

Plot1(st,"Up");
Plot2(st,"Down");
Plot3(st,"SuperTrend",iff(strend = 1,GetPlotColor(1),GetPlotColor(2)));

To get the desired Indicator effect and control over plot colors that I wanted, I made Plot1 and Plot2 a real plot so you could precisely control the RGB color. You need to mark these plots as invisible once you setup the indicator! I will provide a screen shot below as an example.

Plot3 is the real plot, and it will be colored based on if trend is up or down.

[img]https://nexusfi.com/v/pd7kqs.png[/img]

Here are some example screenshots:

[img]https://nexusfi.com/v/qxucdm.png[/img]

[img]https://nexusfi.com/v/4my8dg.png[/img]

[img]https://nexusfi.com/v/mj9exw.png[/img]

Mike

March 26th, 2010, 12:43 AM

Is the name of the function "SuperTrend"?

In OEC we have to combine functions and indicator code into the same file and call the functions manually. Can't get her to compile using SuperTrend as the function name.... is this correct?

March 26th, 2010, 12:45 AM

daedalus

Is the name of the function "SuperTrend"?

In OEC we have to combine functions and indicator code into the same file and call the functions manually. Can't get her to compile using SuperTrend as the function name.... is this correct?

Yes, function name is SuperTrend.

I'm not sure about OEC sorry. If you have to combine them, try taking the function code but using the indicator inputs, then add the plots.. more or less.

Mike

March 26th, 2010, 12:48 AM

Attached is a MultiCharts pla which includes the SuperTrend function, SuperTrend indicator, at the Hull Moving Average I was using. You can replace the Mov Avg (jtHMA) with whatever floats your boat.

Mike

April 1st, 2010, 09:10 AM

[...]
[...]
[...]
[...]

July 5th, 2010, 02:12 PM

Mike-

when does the ATR Mult come into play?

thanks

-Steve

July 5th, 2010, 02:42 PM

factory15

Mike-

when does the ATR Mult come into play?

thanks

-Steve

It doesn't, was a bug in the code I listed above. You just need to modify:

Code

                            
up = avg + (ATR*ATRMult); 

dn = avg - (ATR*ATRMult);

If you want to add it.

Mike

July 5th, 2010, 04:03 PM

Thanks Mike...

if you dont mind me asking- as a CL guy, what numbers do you plug in for ATRLength and Strength typically? Do you find it works pretty well?

I converted this over to thinkscript and I think I've got it working...anxious to see it in action.

thanks again

July 5th, 2010, 06:01 PM

factory15

Thanks Mike...

if you dont mind me asking- as a CL guy, what numbers do you plug in for ATRLength and Strength typically? Do you find it works pretty well?

I converted this over to thinkscript and I think I've got it working...anxious to see it in action.

thanks again

I don't use indicators in my trading, sorry. But the defaults of the script were probably what I used when I wrote it.

Mike