RSI - Thinkscript question...

January 12th, 2015, 05:05 AM

I'm having trouble trying to programmatically add a custom colored "cloud"
a/k/a fill to an RSI study to highlight overbought and oversold conditions as shown below...

FYI, I have been able to successfully plot the shaded overbought (>95) and oversold(<5)
conditions, but I am unable to remove the the unwanted shading between 95 and 5...

Any help/assistance would be greatly appreciated. Thanks in advance...

declare lower;
declare zerobase;

input RSIlength = 2;
input priceH = high;
input priceL = low;
input priceC = close;
input smoothingType = 1;
input over_bought = 95;
input over_sold = 5;

def sf = 1 / RSIlength;

def NetChgAvg = Ema2(data = priceC - priceC[1], prefetch = RSIlength, "smoothing factor" = sf);
def TotChgAvg = Ema2(data = AbsValue(priceC - priceC[1]), prefetch = RSIlength, "smoothing factor" = Sf);

def ChgRatio = if TotChgAvg != 0 then
NetChgAvg / TotChgAvg
else
0;

plot RSI = 50 * (ChgRatio + 1);
RSI.SetDefaultColor(CreateColor(0, 102, 204));
RSI.SetLineWeight(2);

plot OverBought = over_bought;
#OverBought.SetDefaultColor(GetColor(4));
OverBought.hide();

AddCloud(RSI, over_bought, Color.red, Color.red);

plot OverSold = over_sold;
#OverSold.SetDefaultColor(GetColor(4));
OverSold.hide();

AddCloud(RSI, over_sold, Color.red, Color.red);

January 12th, 2015, 05:15 AM

Since my previous post was my fourth, I was unable to post an image to go with the code example, which does a much better job of illustrating what I am trying to accomplish. Hopefully, with this, my fifth post, you should be able to view the image...

January 12th, 2015, 09:31 PM

I worked it out with a little help from a ThinkScripter. Below is the final script for any/all interested parties to review...

declare lower;
declare zerobase;

input RSIlength = 2;
input KPeriod = 14;
input DPeriod = 3;
input priceH = high;
input priceL = low;
input priceC = close;
input smoothingType = 1;
input over_bought = 95;
input over_sold = 5;

def sf = 1 / RSIlength;

def NetChgAvg = Ema2(data = priceC - priceC[1], prefetch = RSIlength, "smoothing factor" = sf);
def TotChgAvg = Ema2(data = AbsValue(priceC - priceC[1]), prefetch = RSIlength, "smoothing factor" = Sf);

def ChgRatio = if TotChgAvg != 0 then
NetChgAvg / TotChgAvg
else
0;

plot RSI = 50 * (ChgRatio + 1);
RSI.SetDefaultColor(CreateColor(0, 102, 204));
RSI.SetLineWeight(2);

plot OverBought = over_bought;
#OverBought.SetDefaultColor(GetColor(4));
OverBought.hide();

AddCloud(if RSI>=95 then RSI else double.nan, over_bought, Color.yellow, Color.yellow);

plot OverSold = over_sold;
#OverSold.SetDefaultColor(GetColor(4));
OverSold.hide();

AddCloud(if RSI<=5 then RSI else double.nan, over_sold, Color.yellow, Color.yellow);

RSI - Thinkscript question...

Discussion in ThinkOrSwim

RSI - Thinkscript question...