SMI Indicator for TradeStation

September 1st, 2009, 06:57 PM

Hi,

I contributed the SMI2New Indicator to the forum months ago and lots of people seem to be using it, which is awesome! I had taken the SMI indicator from Tradestation forums and had hired a programmer to transfer the easy language code to ninjascript then make improvements to it (added the SMIema crossover line, added paintbars, added alerts)

Now, I could you some help. Could someone who knows Ninja and TradeStation please take the current SMI2New indicator (attached below) and and duplicate this back into TradeStation easy language? I don't need any alerts but I'd like an SMI with SMIema and I'd very much like the paintbars in TradeStation.

Sometimes I need to use my TradeStation account to trade and it would help to have this same tool that I use in Ninja back in TS.

I don't know enough about programming to know if this is a big request or a small request. Any help with this is appreciated.

Thanks,
Todd

June 30th, 2011, 03:47 PM

try this:

Code


inputs: Rng(13), EMAPd1(25), EMAPd2(1), SMIEMAPd(25), alertlevel(40);

var: sms(0), hls(0), denom(0.0), smis(0), smiema(0)
;

Plot1(close, "Rising SMI");
Plot2(close, "Falling SMI");
noplot(1);
noplot(2);

if CurrentBar >= EMAPd1 and CurrentBar >= EMAPd2 then begin

    sms = Close[0] - 0.5 * ((Highest(High, range) + lowest(Low, range)));
            
    //High low diffs
    hls = highest(High, range) - Lowest(Low, range);

    //Stochastic Momentum Index = SMI
    denom = 0.5*XAverage(XAverage(hls,emapd1),emapd2);
    value1 = iff(denom = 0, 1, denom);
     smis = 100*XAverage(XAverage(sms,emapd1),emapd2) / value1;
        
    //Set the line value for the SMIEMA by taking the EMA of the SMI
    smiema = XAverage(smis, smiemapd);

    value2 = iff(smis > smis[1], GetPlotColor(1), GetPlotColor(2));
    condition1 = smis crosses below smiema;
    condition2 = smis crosses above smiema;
    
    Plot3(smis, "SMI", value2);
    Plot4(smiema, "SMIEMA");
    
    if condition1 then begin
        // alert
        alert("SMI crosses above signal line");
    end else if condition2 then begin
        // alert
        alert("SMI crosses below signal line");
    end;
end;

Plot5(alertlevel, "Alert");
Plot6(-alertlevel, "Alert");

If you have NT, compare this with a daily chart of something. Let me know if they don't match and I'll fix it.

Regards,
-C

June 30th, 2011, 04:32 PM

Hello all,
long time ago i lesten ..good smi, but never use it , how you use it ?
do you post a graph ...
thank you so much
Serger

November 10th, 2015, 09:22 PM

cbritton

try this:

Thanks, Cbritton! it's a useful code.
Please see updated version below, I fixed input Rng issue as it was not used in the code (there was "range" instead).
And I fixed wrong Alerts order

Code

// www bigmiketrading com/tradestation/654-smi-stochastic-momentum-index-indicator-tradestation.html
{STOCHASTIC MOMENTUM INDEX from William Blau  
}  
inputs: Rng(13), EMAPd1(25), EMAPd2(1), SMIEMAPd(25), alertlevel(40);

var: sms(0), hls(0), denom(0.0), smis(0), smiema(0);

Plot91(close, "Rising SMI");   noplot(91);
Plot92(close, "Falling SMI");  noplot(92);

if CurrentBar >= EMAPd1 and CurrentBar >= EMAPd2 then begin

    sms = Close[0] - 0.5 * ((Highest(High, Rng) + lowest(Low, Rng)));
            
    //High low diffs
    hls = highest(High, Rng) - Lowest(Low, Rng);

    //Stochastic Momentum Index = SMI
    denom = 0.5*XAverage(XAverage(hls,emapd1),emapd2);
    value1 = iff(denom = 0, 1, denom);
     smis = 100*XAverage(XAverage(sms,emapd1),emapd2) / value1;
        
    //Set the line value for the SMIEMA by taking the EMA of the SMI
    smiema = XAverage(smis, smiemapd);

    value2 = iff(smis > smis[1], GetPlotColor(91), GetPlotColor(92));
    
    Plot3(smis, "SMI", value2);
    Plot4(smiema, "SMIEMA");
    
    // alert
    if smis crosses above smiema then begin
        alert("SMI crosses above signal line");
    end else if smis crosses below smiema then begin
        alert("SMI crosses below signal line");
    end;
end;

Plot5(alertlevel, "Alert");
Plot6(-alertlevel, "Alert");

SMI Indicator for TradeStation

Discussion in TradeStation

SMI Indicator for TradeStation